Comparing Java's MessageDigest To ColdFusion's hash() Function In Lucee CFML

<cfscript>

	// A collection of binary data read from different sources.
	parts = [
		// From string data.
		charsetDecode( "This is a string", "utf-8" ),
		// From secure entropy data.
		createObject( "java", "java.security.SecureRandom" )
			.init()
			.generateSeed( 100 )
		,
		// From image data.
		fileReadBinary( "./logo.png" )
	];

	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //

	// TEST ONE: We're going to take the various binary values / byte arrays and hash them
	// all together using the MessageDigest. The nice thing about the MessageDigest class
	// is that you can call .update() multiple times to feed-in the inputs one at a time.
	messageDigest = createObject( "java", "java.security.MessageDigest" )
		.getInstance( "sha-256" )
	;

	for ( part in parts ) {

		messageDigest.update( part );

	}

	// The .digest() method completes the hashing algorithm and returns the bytes for the
	// hash calculation. Since the native hash() method returns hex, let's encode the
	// results as hex for comparison.
	hexEncoding = binaryEncode( messageDigest.digest(), "hex" );

	dump(
		var = hexEncoding,
		label ="Using MessageDigest"
	);

	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //

	// TEST TWO: We're going to take the various binary values / byte arrays and hash them
	// all together using the ColdFusion native hash() function. Unlike MessageDigest,
	// there's no way to incrementally build the hash input. As such, we're going to have
	// to reduce the parts down into a single binary value by appending them all together.
	aggregatedBytes = parts.reduce(
		( reduction, part ) => {

			return( reduction.append( part, true ) );

		},
		[]
	);

	// And, once we have a single COLDFUSION ARRAY of bytes, we have to CAST it to a
	// BINARY value in order to get to get it work with the hash() function.
	hexEncoding = hash( javaCast( "byte[]", aggregatedBytes ), "sha-256" );

	dump(
		var = hexEncoding,
		label = "Using hash()"
	);

	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //

	// TEST THREE: This is the same as TEST TWO, only I want to use a ByteBuffer to
	// aggregate the inputs instead of using javaCast() with the ColdFusion array. This
	// doesn't really add much value; but, I am just trying to fill my head with options.
	buffer = createObject( "java", "java.io.ByteArrayOutputStream")
		.init()
	;

	for ( part in parts ) {

		buffer.write( part );

	}

	hexEncoding = hash( buffer.toByteArray(), "sha-256" );

	dump(
		var = hexEncoding,
		label = "Using hash( byte buffer )"
	);

</cfscript>