Skip to main content
Ben Nadel at NCDevCon 2016 (Raleigh, NC) with: Matthew Eash
Ben Nadel at NCDevCon 2016 (Raleigh, NC) with: Matthew Eash ( @mujimu )

Looping Over Times In ColdFusion

By on
Tags:

Looping over times in ColdFusion is the same exact thing as looping over dates in ColdFusion, but sometimes, people don't quite make the mental leap on their own. And so, I thought I would just quickly demonstrate that this was possible.

The key to looping over times is to understand that a time value is really just a fractional date value and that when looping over it, your loop increment (step value) should also be a fractional time value as well. In this case, we are going to loop from 8:00 AM to 5:00 PM using a one hour increment:

<!---
	When looping over the hours in the day, we are going to
	use an index loop and for each iteration, we are going
	to increase the index by a single hour (the numeric
	timespan representing an hour fraction of the day).
--->
<cfset dtHour = CreateTimeSpan(
	0, <!--- Days. --->
	1, <!--- Hours. --->
	0, <!--- Minutes. --->
	0 <!--- Seconds. --->
	) />


<!---
	When looping over the hours in the day, we can enter the
	start and end time as "readable" time. ColdFusion will
	automatically convert those time strings to their numeric
	equivalents for use within the index loop.
--->
<cfloop
	index="dtTime"
	from="8:00 AM"
	to="5:00 PM"
	step="#dtHour#">

	#TimeFormat( dtTime, "hh:mm TT" )#<br />

</cfloop>

Running the above gives us:

08:00 AM
09:00 AM
10:00 AM
11:00 AM
12:00 PM
01:00 PM
02:00 PM
03:00 PM
04:00 PM
05:00 PM

Notice that in order to get our CFLoop step value, we are building a time span object (returns a Double value) that is created using just a single hour. The mental leap to make here is that that time span value could be anything you want. It could be days, hours, minutes, or seconds.

Just remember, dates are numeric values. Because an indexed CFLoop is iterating over numeric values, ColdFusion accomplishes this by converting your date/time value for the from/to attributes to numeric values behind your back. Embrace this, do not fear it :)

Want to use code from this post? Check out the license.

Reader Comments

15,643 Comments

@Trent,

I just ran this:

<cfset dtHour = CreateTimeSpan( 0, 1, 0, 0 ) />

<cfloop
index="EdtTime"
from="8:00 AM"
to="8:00 PM"
step="#dtHour#">

#TimeFormat( EdtTime, "hh:mm TT" )#<br />

</cfloop>

... and it worked just fine. You have to use the TimeFormat(). Are you? If you don't, it just comes out as fractions.

4 Comments

Hey guys, thanks for the examples. I'm having issues displaying times from 8pm to 4am (see code below). If you copy+paste that, nothing displays. Any help is appreciated.

<cfset dtHour = CreateTimeSpan( 0, 1, 0, 0 ) />

<cfloop
index="EdtTime"
from="8:00 PM"
to="4:00 AM"
step="#dtHour#">

#TimeFormat( EdtTime, "hh:mm TT" )#<br />

</cfloop>

15,643 Comments

@Alan,

You can't do that because there is no "date" involved. As such, it sees those times as already having passed each other (4AM is less than 8PM of the *same* day).

I suspect that in order to get that to work, you would need to add an actual date to the time:

<cfloop
	index="edtTime"
	from="#createDateTime( 2011, 1, 1, 20, 0, 0 )#"
	to="#createDateTime( 2011, 1, 2, 4, 0, 0 )#"
	step="#dtHour#">
 
	... your code ...
 
</cfloop>

This way, you're not just using hours, you actually going from the hours in ONE day to the hours in the NEXT day.

See if that works. The date part is really irrelevant as long as the day in the TO is one more than the day in the FROM.

15,643 Comments

@Alan,

Glad you got it worked out; but, how did military time solve the problem? Wouldn't 20:00 till be greater than 04:00? It seems you'd still have a loop that wouldn't start?

4 Comments

Yes, but you got me thinking about how to "add time" to days, so to speak. Here is what I ended up doing:

<cfset theDate = #form.startDate#>
<cfset theHour = #form.hour#>
 
<cfset dtHour = CreateTimeSpan( 0, 1, 0, 0 ) />
 
<cfset shiftLength=8>
<cfset shiftDateTime=theDate & " " & theHour>
<cfset startTime=ParseDateTime(shiftDateTime)>
<cfset endTime=DateAdd('h',shiftLength,startTime)>
 
<select name="earlyOutHour">
 
	<cfloop index="edtTime" from="#StartTime#" to="#EndTime#" step="#dtHour#">
		<option value="#TimeFormat(EdtTime, "hh:mm TT" )#">#TimeFormat(EdtTime, "hh:mm TT" )#</option>
	</cfloop>
 
</select>
I believe in love. I believe in compassion. I believe in human rights. I believe that we can afford to give more of these gifts to the world around us because it costs us nothing to be decent and kind and understanding. And, I want you to know that when you land on this site, you are accepted for who you are, no matter how you identify, what truths you live, or whatever kind of goofy shit makes you feel alive! Rock on with your bad self!
Ben Nadel