Loading Local Java Class Files Using URLClassLoader

<!---
	Initialize the URL object to point to the current
	directory. In this case we are pointing using the file
	system, NOT the web browser, hence the "file:" prefix. This
	URL can point to any part of the file system irrelevant of
	the web-accessible parts of the system. This will happen on
	the server size, not the client side (of course) and
	therefore is not dependent on web-accessibility.
--->
<cfset objUrl = CreateObject( "java", "java.net.URL" ).Init(
	JavaCast(
		"string",
		"file:" & ExpandPath( "./" )
		)
	) />


<!---
	Get an array of URL objects. Since we cannot do this
	directly, (delcare an array of java object types), we will
	have to do this using the reflect array class. We can pass
	this class a Java class definition and ask it to create an
	array of that type for us.
--->
<cfset objArrayCreator = CreateObject(
	"java",
	"java.lang.reflect.Array"
	) />

<!---
	Ask the reflect array service to create an array of URL
	objects. Get the class definition from the URL object we
	created previously. When we create the array, we need to
	create it with the length of 1 so that we can add the URL
	to it next.
--->
<cfset arrURL = objArrayCreator.NewInstance(
	objUrl.GetClass(),
	JavaCast( "int", 1 )
	) />


<!---
	Now, we need to set the URLs into the array. This array
	will be used for the initialization of the URL class loader
	and will need to contain all the URLs that we need. Since
	we cannot work with these types of array directly in
	ColdFusion, we need to ask our array creator object to do
	the setting for us.

	My hope was that we did NOT have to use this SET method. I
	had hoped that I could call the AddURL() method on the
	URLClassLoader itself. Unforutnately, that method is
	Protected and I do not have permissions to access it.
	Hence, all of the URLs that we want to load have to be
	passed in during the initialization process.
--->
<cfset objArrayCreator.Set(
	arrURL,
	JavaCast( "int", 0 ),
	objUrl
	) />


<!---
	Now, we want to create a URL class loader to load in the
	Java classes that we have locally. In order to initialize
	this class, we need to pass it the URL array that we just
	created. Keep in mind that it contains all the URLs that
	we want to load.
--->
<cfset objClassLoader = CreateObject(
	"java",
	"java.net.URLClassLoader"
	).Init(
		arrURL
		)
	/>


<!---
	Now, get the URL class loader to load the HelloWorld.class
	class. Once it loads the class, we have to get a new
	instance of the Java class, HelloWorld.
--->
<cfset objHelloWorld = objClassLoader.LoadClass(
	"HelloWorld"
	).NewInstance() />


<!---
	Get the hello world object to perform an action. This should
	output the phrase "Hello World". This will show us that
	everything is working nicely.
--->
<cfoutput>
	#objHelloWorld.SayHello()#<br />
</cfoutput>