Making CFDump Easier To Read As I Get Older

<cfscript>

	/**
	* I polyfill the dump() function in Adobe ColdFusion.
	*/
	private void function dump(
		required any var,
		boolean expand = true,
		string format = "html",
		string hide = "",
		numeric keys = 9999,
		string label = "",
		string output = "browser",
		string show = "all",
		boolean showUDFs = true,
		numeric top = 9999,
		boolean abort = false
		) {

		// Note: under the hood, Adobe ColdFusion seems to be compiling this down into an
		// instance of the CFDump tag (based on error messages). As such, it's much more
		// temperamental than a normal function invocation (include my attempts at using
		// the argumentCollection construct). We have to be much more explicit in our
		// argument pass-through; and, certain attributes CANNOT be passed in as NULL.
		writeDump(
			var = var,
			expand = expand,
			format = format,
			hide = hide,
			keys = keys,
			label = label,
			output = output,
			show = show,
			showUDFs = showUDFs,
			top = top,
			abort = abort
		);

		// If we're outputting to the browser (the default behavior), inject custom styles
		// for better readability for my aging eyes.
		if ( output == "browser" ) {

			dumpStyles();

		}

	}

	/**
	* I inject style tags that make the CFDump output easier to read.
	*/
	private void function dumpStyles() {

		// For better debugging on how these styles are being injected, we're going to
		// include the call-stack in the style tag content (as a comment).
		var stacktrace = callStackGet()
			.map( ( frame ) => "- #frame.template#:#frame.lineNumber#" )
			.toList( chr( 10 ) & repeatString( chr( 9 ), 4 ) & "* " )
		;

		// CAUTION: Normally, the use of cfhtmlhead() is considered an ANTI-PATTERN due to
		// its total lack of accountability. But, in this case, we're fighting fire with
		// fire. Meaning, the writeDump() tag is already injecting styles magically; and
		// now, we're also injecting styles magically to counteract their magical styles.
		cfhtmlhead( text = "
			<style type='text/css' data-source='Added by the dumpStyles().'>
				/**
				* ColdFusion Stacktrace:
				* #stacktrace#
				**/

				html body table[class^='cfdump_'] {
					border-collapse: separate ;
					border-spacing: 2px ;
					font-family: verdana, arial, helvetica, sans-serif ;
					margin-bottom: 1.5rem ;

					& table[class^='cfdump_'] {
						margin-bottom: 0 ;
					}

					& th,
					& td {
						font-size: 1rem ;
						padding: 0.4em 0.55em ;
					}
				}
			</style>
		");

	}

</cfscript>

<cfscript>

	writeDump([
		{ id: 1, name: "Kim",  role: "Admin" },
		{ id: 2, name: "Jon",  role: "Engineer" },
		{ id: 3, name: "Kali", role: "Manager" },
	]);

</cfscript>

<cfscript>

	// ColdFusion language extensions (global functions).
	include "/core/cfmlx.cfm";

	// Note: this is the dump() POLYFILL I've created in the CFMLX template.
	dump([
		{ id: 1, name: "Kim",  role: "Admin" },
		{ id: 2, name: "Jon",  role: "Engineer" },
		{ id: 3, name: "Kali", role: "Manager" },
	]);

</cfscript>