Image Paste Bug In Lucee CFML

<cfscript>

	// The only difference in the two tests is that one will perform imagePaste().
	tests = [ false, true ];

	results = tests.map(
		( doPaste ) => {

			var black = imageNew( "", 20,  20,  "rgb", "000000" );
			var white = imageNew( "", 100, 100, "rgb", "ffffff" );

			// Draw MAGENTA boxes BEFORE paste.
			white.setDrawingColor( "ff3366" );
			white.drawRect( 10, 10, 20, 20, true );
			white.drawRect( 30, 30, 20, 20, true );
			white.drawRect( 50, 50, 20, 20, true );
			white.drawRect( 70, 70, 20, 20, true );

			// Pasting one image into another seems to corrupt the destination image
			// (in Lucee CFML); and, prevents subsequent image manipulation operations.
			if ( doPaste ) {

				white.paste( black, 70, 10 );

			}

			// Draw CYAN boxes AFTER paste.
			white.setDrawingColor( "008b8b" );
			white.drawRect( 10, 40, 10, 10, true );
			white.drawRect( 30, 60, 10, 10, true );
			white.drawRect( 50, 80, 10, 10, true );

			return white;

		}
	);

</cfscript>
<cfoutput>

	<cfloop array="#results#" item="image" index="i">

		<div>
			<!--- Write the image to disk. --->
			<cfimage
				source="#image#"
				action="write"
				destination="#expandPath( './#i#.png' )#"
				overwrite="true"
			/>

			<!--- Render image we JUST wrote to disk. --->
			<img src="./#i#.png" />
			<cfdump var="#imageInfo( image )#" />
		</div>

	</cfloop>

</cfoutput>