Skip to main content
Ben Nadel at cf.Objective() 2009 (Minneapolis, MN) with: Oguz Demirkapi
Ben Nadel at cf.Objective() 2009 (Minneapolis, MN) with: Oguz Demirkapi ( @demirkapi )

StructCopy() Duplicates Argument-Collection Functionality Without Deep Copy In ColdFusion

By on
Tags:

In ColdFusion, the Arguments-Collection object is an objectively awesome object because it allows us to access a function's CFArgument values using either named-keys or ordered-indices. That's way cool! When I was writing my last post on ArraySplice(), I thought it would be nice to be able to duplicate the argument collection without performing a deep copy. My initial concerns over ColdFusion's various copy methods were as follows:

  • StructCopy() - Would return a struct, thereby losing the index-based lookup.
  • Duplicate() - Would perform a deep copy, breaking pass-by-reference bindings.

As it turns out, however, my fear of StructCopy() was unfounded. Apparently, ColdFusion's StructCopy() function will work with both structs as well as argument collections. To see this in action, take a look at this demo:

<cffunction
	name="doCopy"
	access="public"
	returntype="void"
	output="false"
	hint="I try to copy the arguments scope.">

	<!--- Define arguments. --->
	<cfargument
		name="value"
		type="struct"
		required="true"
		hint="I am STRUCT object."
		/>

	<!--- Copy the arguments. --->
	<cfset var copy = structCopy( arguments ) />

	<!--- Update the first arguments (copy) by index. --->
	<cfset copy[ 1 ].name = "Sarah" />

	<!--- Return out. --->
	<cfreturn />
</cffunction>

<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->

<!---
	Create a struct with a key-value we can manipulate.
	It's important that this is a struct so that it is
	pass-by-reference.
--->
<cfset friend = {
	name = "Kate"
	} />

<!--- Call our test method. --->
<cfset doCopy( friend ) />

<!--- Output friend's name. --->
<cfoutput>
	Name: #friend.name#
</cfoutput>

As you can see, I am passing in a struct to the test method; because structs are passed-by-reference, any updates that I make to the struct within the user defined function should be reflected in the original struct. Once inside the UDF, I copy the arguments scope and then update its contents by-index. When running the above code, we get the following output:

Name: Sarah

As you can see, the name of the friend was changed in the original object (from Kate to Sarah) - StructCopy() kept the original references.

This was very surprising! But, when I first saw this, I wanted to be sure that the StructCopy() wasn't merely copying both the keys and indices from the argument collection. To confirm that this wasn't the case, I CFDump'd out the arguments scope and its copy inside the UDF (post-update). Here is what I get:

StructCopy() Of ColdFusion's Arguments Scope (Argument Collection) Returns An Argument Collection Object.

As you can see, there are no visible index values even though we updated the friend's name by way of an index value. StructCopy() truly creates a top-level copy of the ColdFusion's argument collection (and outputting the underlying Java class name confirms this). Sweet ass sweet!

Want to use code from this post? Check out the license.

Reader Comments

2 Comments

wow! have the what I call a quick response xD I save you under my favorites and when i have a question about javascript, i will ask you when you allow ^^

15,377 Comments

@Kyle,

My pleasure. Duplicate() is a good function - you just have to be aware that it does a deep copy (duplicating even CFCs in newer versions of ColdFusion).

I believe in love. I believe in compassion. I believe in human rights. I believe that we can afford to give more of these gifts to the world around us because it costs us nothing to be decent and kind and understanding. And, I want you to know that when you land on this site, you are accepted for who you are, no matter how you identify, what truths you live, or whatever kind of goofy shit makes you feel alive! Rock on with your bad self!
Ben Nadel