Listing All Classes In A Jar File Using ColdFusion

<cffunction
	name="GetJarClasses"
	access="public"
	returntype="array"
	output="false"
	hint="I return an array of classes in the given JAR file (expanded path).">

	<!--- Define arguments. --->
	<cfargument
		name="JarFilePath"
		type="string"
		required="true"
		hint="I am the expanded path of the JAR file."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />

	<!--- Create a default array of classes. --->
	<cfset LOCAL.Classes = [] />


	<!---
		Create a JAR input stream to read in the line items
		from our target JAR file.
	--->
	<cfset LOCAL.JarFile = CreateObject(
		"java",
		"java.util.jar.JarInputStream"
		).Init(

			CreateObject(
				"java",
				"java.io.FileInputStream"
				).Init(

					JavaCast(
						"string",
						ARGUMENTS.JarFilePath
						)
				)
			)
		/>


	<!---
		Now that we have our JAR file input stream, let's loop
		over all the entries looking for CLASS files.
	--->
	<cfloop condition="true">

		<!---
			Get the next entry. This might return NULL if the
			JAR file has no more classes.
		--->
		<cfset LOCAL.JarEntry = LOCAL.JarFile.GetNextJarEntry() />

		<!---
			Check to see if the entry variable exists. If it
			does not, then it means the JAR file return NULL
			and we are done finding classes.
		--->
		<cfif StructKeyExists( LOCAL, "JarEntry" )>

			<!---
				Check to make sure that this entry is not a
				directory, but is, in fact a class.
			--->
			<cfif REFindNoCase( "\.class$", LOCAL.JarEntry.GetName() )>

				<!---
					Add this class to the array. Since the JAR
					file really has a directory structure, let's
					replace the path separators with dots.
				--->
				<cfset LOCAL.ClassName = REReplace(
					LOCAL.JarEntry.GetName(),
					"[\\/]",
					".",
					"all"
					) />

				<!--- Strip off the ".class" path item. --->
				<cfset LOCAL.ClassName = REReplaceNoCase(
					LOCAL.ClassName,
					"\.class$",
					"",
					"one"
					) />

				<!--- Add the formatted class name. --->
				<cfset ArrayAppend(
					LOCAL.Classes,
					LOCAL.ClassName
					) />

			</cfif>

		<cfelse>

			<cfbreak />

		</cfif>

	</cfloop>


	<!--- Return the array of classes. --->
	<cfreturn LOCAL.Classes />
</cffunction>

<!--- Get file path to POI installed JAR file. --->
<cfset strJarFilePath = ExpandPath(
	"./poi-2.5.1-final-20040804.jar"
	) />

<!--- Output the classes. --->
<cfdump
	var="#GetJarClasses( strJarFilePath )#"
	label="POI 2.5.1 Final Classes"
	/>