Ask Ben: Creating An Archive Folder / File List (Part II)

Posted February 24, 2007 at 10:38 AM

Tags: ColdFusion, Ask Ben

A while back, I was asked how to make a simple ColdFusion page that would allow the viewing of archive folders and their contents. At the time, the page was designed to handle a single list of directories and then a single list of sub-files. I have been asked to update that code to allow for sub-directories and sub-sub-directories (you get the point).

Below is the updated code that allows for a single page to point to a directory and drill down through all the sub directories. All files are linked directly. All sub folders get viewed via the URL.folder variable that keeps getting passed back to the same ColdFusion script.

I am not taking into account the different slashes on different platforms. For this demo, the backward slash is considered a "server" slash for a server path and the forward slash is considered a "web" slash for web-based paths (ie. URLs).

 Launch code in new window » Download code as text file »

  • <!--- Kill extra output. --->
  • <cfsilent>
  •  
  • <!---
  • This is the name of the archive folder for which we
  • want to list out the archive documents and sub folders.
  • --->
  • <cfparam
  • name="URL.folder"
  • type="string"
  • default=""
  • />
  •  
  • <!--- Decode the folder value. --->
  • <cfset URL.folder = UrlDecode( URL.folder ) />
  •  
  • <!---
  • For security reasons, we want to get rid of any suspect
  • values in the folder variable. These include "../"
  • which would go to a parent directory or "/" which will
  • go to the root perhaps.
  • --->
  • <cfset URL.folder = URL.folder.ReplaceAll(
  • "(\.\.[\\/])+", ""
  • ).ReplaceAll(
  • "([\\/]){2,}", "$1"
  • ) />
  •  
  • <!---
  • Set the directory path of the root archive
  • directory (this one). This is the folder in which
  • you want to allow users to browse archive folders
  • and files.
  • --->
  • <cfset strRoot = ExpandPath( "./" ) />
  •  
  •  
  • <!---
  • Check to see if we have an archive folder selected.
  • If we do, then we want to query that one. If not,
  • then we want to get the list of all the archive folders.
  • Furthermore, if we have an archive folder, just
  • check to make sure the folder exists.
  • --->
  • <cfif (
  • Len( URL.folder ) AND
  • DirectoryExists( strRoot & "\" & URL.folder )
  • )>
  •  
  • <!--- Set the query path to be the archive folder. --->
  • <cfset strQueryPath = (strRoot & "\" & URL.folder) />
  •  
  • <!---
  • Add the trailing slash to the folder for use with
  • further linking. Going foward, we can assume the
  • the folder variable will have this trailing slash.
  • --->
  • <cfset URL.folder = (URL.folder & "\") />
  •  
  • <cfelse>
  •  
  • <!---
  • We have no archive folder selected (or it did not
  • exist). Query the root directory.
  • --->
  • <cfset strQueryPath = strRoot />
  •  
  • <!---
  • Reset the folder variable so we don't get confused
  • later on.
  • --->
  • <cfset URL.folder = "" />
  •  
  • </cfif>
  •  
  •  
  • <!---
  • Query for the files / folders in the selected
  • directory (might be root OR an archive folder).
  • --->
  • <cfdirectory
  • action="LIST"
  • directory="#strQueryPath#"
  • recurse="false"
  • name="qDirectoryList"
  • />
  •  
  • </cfsilent>
  •  
  • <cfoutput>
  • <html>
  • <head>
  • <title>Document Archive</title>
  • </head>
  • <body>
  •  
  • <h1>
  • Document Archive
  • </h1>
  •  
  • <!---
  • Check to see if we are deeper than the root directory.
  • We will know that we are if our folder variable has
  • some value in it. If it does, we will provide tools
  • to jump up a single directory or to go back to the
  • archivee root.
  • --->
  • <cfif Len( URL.folder )>
  •  
  • <h2>
  • #URL.folder#
  • </h2>
  •  
  • <p>
  • &laquo; <a href="#CGI.script_name#">Back to Archive Root</a>
  • </p>
  •  
  •  
  • <!---
  • When outputting the parent directory path, be sure
  • to strip out the last directory and traililng slash
  • from the existing folder path.
  • --->
  • <p>
  • &laquo; <a href="#CGI.script_name#?folder=#UrlEncodedFormat( URL.folder.ReplaceAll( "[\\/]?[^\\/]+[\\/]?$", "" ) )#">Back to Parent Directory</a>
  • </p>
  •  
  • <hr />
  •  
  • </cfif>
  •  
  •  
  • <!---
  • Loop over directory list. This may contain both files
  • and folders. If we come across a folder or sub
  • directory, then we will provide a link to view that
  • directory (through the archive viewer). If we come
  • across a file, we will link directly to that file.
  • --->
  • <cfloop query="qDirectoryList">
  •  
  • <!---
  • Check to see if we are dealing with a sub folder.
  • --->
  • <cfif (qDirectoryList.Type EQ "Dir")>
  •  
  • <!---
  • We are dealing with a directory. Add this folder
  • name to the folder path we are sending back
  • in the URL. Since we are dealing with a server
  • path at this point, replace any "Web" slashes
  • with "server" slashes... / -to- \.
  • --->
  • <p>
  • <a href="#CGI.script_name#?folder=#UrlEncodedFormat( URL.folder.ReplaceAll( "/", "\\" ) & qDirectoryList.name )#">#qDirectoryList.name#</a> &raquo;
  • </p>
  •  
  • <cfelse>
  •  
  • <!---
  • We are dealing with a file. Output the link
  • to the file from the root directory (since
  • that is where we still are from the browser's).
  • standpoint. Include the name of the sub folder
  • in the path. Since we are dealing with a web
  • path, replace all "server" slashes with "web"
  • slashes... \ -to- /.
  • --->
  • <p>
  • <a href="./#URL.folder.ReplaceAll( "\\", "/" )##qDirectoryList.name#">#qDirectoryList.name#</a>
  • </p>
  •  
  • </cfif>
  •  
  • </cfloop>
  •  
  • </body>
  • </html>
  • </cfoutput>

Hope that helps.

Download Code Snippet ZIP File

Post Comment  |  Ask Ben  |  Permalink  |  Print Page


You Might Also Be Interested In:



Learning ColdFusion 9 - ColdFusion 9 tutorials, samples, examples, demos

Reader Comments

There are no comments posted for this web log entry.


Post Comment  |  Ask Ben

Recent Blog Comments
komik
Nov 21, 2009 at 6:47 PM
Hal Helms - Real World Object Oriented Development, Sarasota - Day Five
@charlie griefer, Thank you.. ... read »
Jody Fitzpatrick
Nov 21, 2009 at 5:15 PM
Using ColdFusion Structures To Remove Duplicate List Values
@Jose Galdamez, Oh heh yeah I didn't paste the whole code. I should have defined the vars -- my bad. It's fixed thou. Thanks. ... read »
Unibands
Nov 21, 2009 at 4:49 PM
Styling The ColdFusion 8 WriteToBrowser CFImage Output
Great work yet again Ben! Whilst I didn't use this whole code, I copied some of your regex code for a similar problem with the lack of an alt attribute and unescaped ampersands in CFIMAGE for Railo 3 ... read »
Justice
Nov 21, 2009 at 1:13 PM
My First ColdFusion Builder Extension - Encrypting And Decrypting CFM / CFC Files
@Ben, Because I am pedantic, I just want to make sure that everyone knows there is absolutely no encryption going on. There is only encoding and obfuscation. The cfencode tool only obfuscates your C ... read »
Jose Galdamez
Nov 21, 2009 at 12:28 PM
Using ColdFusion Structures To Remove Duplicate List Values
@Jody I can't seem to get your code sample to work. If you are still having problems, try this code out and see if it gets you what you wanted. <!--- Comma delimited list with various duplicates ... read »
Esther Annies
Nov 21, 2009 at 11:03 AM
Groovy Operator Overloading Does Not Work In The ColdFusion Context
Hi Ben, Thanks for this informative post. Now I am reading ur old posts too ... read »
Henry Parker
Nov 21, 2009 at 10:56 AM
HostMySite.com Has The Best ColdFusion Hosting
@Mehul, Yes very nice people, however several downtimes per day which was not acceptable. Hence we had to move out. I am glad you are having good luck with them so far. ... read »
<scriptalert('just a test buddy :)')script
Nov 21, 2009 at 12:41 AM
Ask Ben: Building An AJAX, jQuery, And ColdFusion Powered Application
13311qseqweqwe ... read »