<cffunction 
	name="GetJavaClassMethodParameters" 
	access="public" 
	returntype="string" 
	output="false" 
	hint="Returns the arguments that are required for the given Java method call.">
	 
	<!--- Define arguments. --->
	<cfargument name="Method" type="any" />
	 
	<!--- Define the local scope. --->
	<cfset var LOCAL = StructNew() />
	 
	<!--- Get the parameters. --->
	<cfset LOCAL.Parameters = ARGUMENTS.Method.GetParameterTypes() />
	 
	<!--- Set up the results. --->
	<cfset LOCAL.ParamList = "" />
	 
	<!--- Loop over the parameters. --->
	<cfloop 
		index="LOCAL.ParameterIndex" 
		from="1" 
		to="#ArrayLen( LOCAL.Parameters )#" 
		step="1">
		 
		<cfset LOCAL.ParamList = ListAppend( 
			LOCAL.ParamList, 
			LOCAL.Parameters[ LOCAL.ParameterIndex ].GetName()
			) />
	 
	</cfloop>
	 
	<!--- Space out the parameters (visual difference only). --->
	<cfset LOCAL.ParamList = Replace( 
		LOCAL.ParamList, 
		",", 
		", ",
		"ALL" 
		) />
	 
	<!--- Return the parameter list. --->
	<cfreturn LOCAL.ParamList /> 
</cffunction>