Ben Nadel
On User Experience (UX) Design, JavaScript, ColdFusion, Node.js, Life, and Love.
I am the chief technical officer at InVision App, Inc - a prototyping and collaboration platform for designers, built by designers. I also rock out in JavaScript and ColdFusion 24x7.
Meanwhile on Twitter
Loading latest tweet...
Ben Nadel at Scotch On The Rock (SOTR) 2010 (Munich) with:

Copying Children From One ColdFusion XML Document To Another

Posted by Ben Nadel
Tags: ColdFusion

The other day, Matthew Abbott had contacted me to ask about some advanced JDOM libraries. I have not used JDOM directly in any way so I couldn't really help him. But this got me thinking about XML in general but more specifically, about XML in ColdFusion. I just don't use it that often and certainly, I don't do anything cool with it. So, I thought I would take this opportunity to try some cool stuff.

For this experimentation, I have created two XML document objects: xmlDate and xmlGirls. The xmlDate XML document outlines the agenda for a hot date (who doesn't love pizza and a movie???). The xmlGirls XML document is an XML database of girls:

  • <!---
  • Build our XML data object to outline the activities
  • of our date. Right now, we only have information about
  • the girl by way of her foriegn key ID.
  • --->
  • <cfxml variable="xmlDate">
  •  
  • <date>
  • <girl id="4" />
  • <meal>
  • <location>Ben's Pizza</location>
  • <time>7:30 PM</time>
  • </meal>
  • <movie>
  • <name>Friends With Money</name>
  • <time>9:15 PM</time>
  • </movie>
  • </date>
  •  
  • </cfxml>
  •  
  •  
  • <!---
  • Here is our XML data object that holds the more detailed
  • information about our girls. We can use the IDs here to
  • populate foreign references to these girls.
  • --->
  • <cfxml variable="xmlGirls">
  •  
  • <girls>
  • <girl id="1">
  • <name>Kit Cat</name>
  • <hair>Brunette</hair>
  • <eyes>Blue</eyes>
  • </girl>
  • <girl id="4">
  • <name>Anna Banana</name>
  • <hair>Brunette</hair>
  • <eyes>Brown</eyes>
  • </girl>
  • <girl id="5">
  • <name>Marcie Darcey</name>
  • <hair>Blonde</hair>
  • <eyes>Brown</eyes>
  • </girl>
  • </girls>
  •  
  • </cfxml>
  •  
  •  
  • <!--- Dump out our date. --->
  • <cfdump
  • var="#xmlDate#"
  • label="xmlDate XML Data"
  • />
  •  
  • <!--- Dump out our girls. --->
  • <cfdump
  • var="#xmlGirls#"
  • label="xmlGirls XML Data"
  • />

CFDumping out the xmlDate XML document, we get:


 
 
 

 
ColdFusion XML Document Object Model For xmlDate  
 
 
 

CFDumping out the xmlGirls XML document, we get:


 
 
 

 
 
 
 
 

Now, our XML document about the date has the girl's ID, but that doesn't really help us out much. What we want to do is copy the properties of the girl from the xmlGirls document to the Girl node of the xmlDate document. My first thought about this was, no problem, just use the AddAll() method for the child nodes collection:

  • <!---
  • Add the girl properties to the girl node
  • of our date XML docuemnt.
  • --->
  • <cfset xmlDate.Date.Girl.XmlChildren.AddAll(
  • xmlGirls.Girl[ 2 ].XmlChildren
  • ) />

The problem is that when you run the above code, you get the following ColdFusion error:

WRONG_DOCUMENT_ERR: A node is used in a different document than the one that created it.

The issue, which I had never thought about, was that each Node of an XML document is owned by that document. You can't just use a single XML node in two different places and especially NOT in two different XML documents (just as I can't be both at work and at the movies at the same time!!!).

So, how do we get around this? We have to import the girl node into our xmlDate document before we try and insert it somewhere into our xmlDate XML document object model. To help accomplish this, I have come up with a ColdFusion user defined function, XmlAppend(). This UDF takes two XML nodes from two different XML documents (one from each) and then appends the child nodes of the latter to the child nodes of the former:

  • <cffunction
  • name="XmlAppend"
  • access="public"
  • returntype="any"
  • output="false"
  • hint="Copies the children of one node to the node of another document.">
  •  
  • <!--- Define arguments. --->
  • <cfargument
  • name="NodeA"
  • type="any"
  • required="true"
  • hint="The node whose children will be added to."
  • />
  •  
  • <cfargument
  • name="NodeB"
  • type="any"
  • required="true"
  • hint="The node whose children will be copied to another document."
  • />
  •  
  •  
  • <!--- Set up local scope. --->
  • <cfset var LOCAL = StructNew() />
  •  
  • <!---
  • Get the child nodes of the originating XML node.
  • This will return both tag nodes and text nodes.
  • We only want the tag nodes.
  • --->
  • <cfset LOCAL.ChildNodes = ARGUMENTS.NodeB.GetChildNodes() />
  •  
  •  
  • <!--- Loop over child nodes. --->
  • <cfloop
  • index="LOCAL.ChildIndex"
  • from="1"
  • to="#LOCAL.ChildNodes.GetLength()#"
  • step="1">
  •  
  •  
  • <!---
  • Get a short hand to the current node. Remember
  • that the child nodes NodeList starts with
  • index zero. Therefore, we must subtract one
  • from out child node index.
  • --->
  • <cfset LOCAL.ChildNode = LOCAL.ChildNodes.Item(
  • JavaCast(
  • "int",
  • (LOCAL.ChildIndex - 1)
  • )
  • ) />
  •  
  • <!---
  • Import this noded into the target XML doc. If we
  • do not do this first, then COldFusion will throw
  • an error about us using nodes that are owned by
  • another document. Importing will return a reference
  • to the newly created xml node. The TRUE argument
  • defines this import as DEEP copy.
  • --->
  • <cfset LOCAL.ChildNode = ARGUMENTS.NodeA.GetOwnerDocument().ImportNode(
  • LOCAL.ChildNode,
  • JavaCast( "boolean", true )
  • ) />
  •  
  • <!---
  • Append the imported xml node to the child nodes
  • of the target node.
  • --->
  • <cfset ARGUMENTS.NodeA.AppendChild(
  • LOCAL.ChildNode
  • ) />
  •  
  • </cfloop>
  •  
  •  
  • <!--- Return the target node. --->
  • <cfreturn ARGUMENTS.NodeA />
  • </cffunction>

Once we have this nifty ColdFusion XML UDF, we can easily copy the girl properties from the xmlGirls document to the xmlDate document:

  • <!---
  • Get the ID of the girl we are going to be taking
  • out on the date. We want to get more information
  • about her in our date data object.
  • --->
  • <cfset intDateID = xmlDate.Date.Girl.XmlAttributes.ID />
  •  
  • <!---
  • Search for the matching girl in our girl xml data
  • object. When searching with XPath, search for a
  • girl with the given ID. All we need is the ID since
  • each girl has a unique ID.
  • --->
  • <cfset arrGirls = XmlSearch(
  • xmlGirls,
  • "//girl[@id=#intDateID#]"
  • ) />
  •  
  •  
  • <!---
  • Check to see if we found a matching girl in our
  • girl date object.
  • --->
  • <cfif ArrayLen( arrGirls )>
  •  
  • <!---
  • Our XPath search above has returned a matching
  • girl. Now, we want to append those returned girl's
  • properties child nodes) to the girl node of our
  • Date data object.
  • --->
  • <cfset XmlAppend(
  • xmlDate.date.girl,
  • arrGirls[ 1 ]
  • ) />
  •  
  • </cfif>
  •  
  •  
  • <!--- Dump out the resultant XML date document. --->
  • <cfdump
  • var="#XmlDate#"
  • label="xmlDate After Girl Node Import"
  • />

Once the node is copied, our resultant xmlDate XML document looks like this:


 
 
 

 
ColdFusion XML Document Object Model For xmlDate After XmlAppend()  
 
 
 

The girl properties of Girl ID 4 copies over quite nicely. This is some very interesting stuff. It gives me all sorts of ideas about building xml documents in pieces and then easily joining them together to make a bigger, better document (like denormalizing a database).




Reader Comments

Wow! This is a pretty impressive technique.

Do you know where documentation exists that talks about these built-in functions within the XML document object? I've only ever been familiar with the functions in the CF documentation, which aren't nearly this powerful.

Thanks in advance,
Toby

Reply to this Comment

On a recent project, I had the need to copy one node to another 'parent' node. I just used duplicate() on the node and it worked fine.

I was told by a co-worker that it would not work because every XML node has a 'parentNode'. Apparently in CFMX 7, Cf is smart enough to remove that reference when you duplicate(). I am not certain how this would work if I tried to move it to a completely different XML document.

Reply to this Comment

@Chris,

That looks pretty cool. I know nothing about XSLT (I have tried to learn it but I just can't seem to get a handle on its seemly irregular programming syntax). I like what you are doing; my only issue with it is that you have to re-parse XML, which might have a lot of over head.

Cool stuff though. I really should learn more about XSLT.

Reply to this Comment

@Matt,

That is some interesting stuff. I have not done anything with XML outside of the core ColdFusion installed libraries. I will have to take a look at that other stuff sometime.

Reply to this Comment

Just wanted to say thanks for writing this comment! I ran into this same issue while doing some XML work today, and this saved me a TON of headache. Thanks!

Reply to this Comment

Hey ben this is great and it almost solved my problem. Im trying to import a specific child to another xml document in the same parent. I tried to tweak your function to accept a new argument for a specific child but it doesnt seem to be working. Some of these functions are new to me.

Reply to this Comment

This worked great for manipulating a Word 2003 XML document. I'm using it to insert the contents of one document into another.

Reply to this Comment

So this will work with merging a bunch of xml documents that are identical in structure?

Reply to this Comment

Yup. Basically I have information coming in from many different sources. It is the same format so it would be nice to have an easy way to just merge the documents. Right now I have to parse each one and build a master. Many steps and very slow since they can have up to a million + entries between them all. (Sales information).

Twould be nice to just say XMLMerge(doc1,doc2) or something like that.

Reply to this Comment

@Don,

I've been thinking about this issue and the one thing that I realize will happen is that ColdFusion won't have the ability to hold such a large XML file in memory. Why are you trying to merge them? For transfer?

Reply to this Comment

Hi Ben,
just out of curiosity, why didn't you do the code to also copy the attributes of NodeA to NodeB if Any? Is there a specific reason? I did the code, I'm just wondering if there is anything I should know.

Thanks
Faisal

Reply to this Comment

How about this one -
If you work with the Amazon API for products, you know that the nodes come out basically in reverse order for any item. It will give you the node for the product, then the parent, then for the parent it gives the grandparent and so on. All digging deeper into the xml.
<node>
<ancestor>
<node>
<ancsetor>
.... up to top level node
</ancestor>
</node>
</ancestor>
</node>
So how to flip it around so I have an xml doc with the top level node (category) on down?
Lots of work. That's how. sigh.
Actually I'm thinking of converting it to an array and then going from there. Or a structure.

Reply to this Comment

@Faisal,

I believe the node import bring the attributes along with it.

@Don,

Hmmm, sounds funky. I assume they are returning it that way for a practical reason?? I don't have much experience with Amazon's web services (just played around with it once or twice).

Reply to this Comment

Hi, I would like to know if this is possible?

If yoou have:

<cfxml variable="xmlDate">

<date>

<meal>
<location>Ben's Pizza</location>
<time>7:30 PM</time>
</meal>

<movie>
<name>Friends With Money</name>
<time>9:15 PM</time>
</movie>

</date>

</cfxml>

And:

<cfxml variable="xmlGirls">

<girls>
<girl id="1">
<name>Kit Cat</name>
<hair>Brunette</hair>
<eyes>Blue</eyes>
</girl>
<girl id="4">
<name>Anna Banana</name>
<hair>Brunette</hair>
<eyes>Brown</eyes>
</girl>
<girl id="5">
<name>Marcie Darcey</name>
<hair>Blonde</hair>
<eyes>Brown</eyes>
</girl>
</girls>

</cfxml>

And you want to add girls as children of the root element date...
Thanks :)

Reply to this Comment

@Christophe,

The code I have above is for copy one node's children to the child nodes of another node (in another document). Since you want to add the ROOT element of one XML document to the children of another node (in another document), you'd have to update the code to work with that.

I think it would work in basically the same way - you'd have to access the underlying Java methods on the root node to change it's document owner.

Reply to this Comment

Okay, 2 answers long time coming.
1 - The reason to merge the documents is for reporting purposes. The full document would only be created once each day at night. The server it is done on has 12G of ram so that is not a problem. (Dual quad core wooo hooo). I finally just said to myself "self, just chop off the top level opening and closing of each document, put them together, and then put the opening and closing back on." Works well.
2 - Why does Amazon do what it does? Who knows. lol I have found many of these big companies are trying to create their own way of doing APIs etc forcing us developers to jump through hoops. I think it may be like IE marching to the beat of a different drum but being big enough to force others to follow along.
Google is doing this too in their new Analytics API. What a nightmare they have there. It is like "Geeks Gone Wild". They were told "Come up with something that will confuse the snot out of the average developer just to show how smart you are"

arg

Reply to this Comment

@Don,

Ha ha, Geeks gone wild :) It sounds like you might want to explore some XML transform stuff if you need to get Amazon nodes in a different order (sorry, I sort of lost the conversation a bit).

Reply to this Comment

Pretty sure that Xml Objects in coldfusion are collections of arrays and structs.

There is a reference here which says you can use all the native array and struct functions to manipulate the xml

http://www.co.multnomah.or.us/cfdocs/Developing_ColdFusion_MX_Applications_with_CFML/XML7.html

Reply to this Comment

@Tony,

You can definitely treat XML objects like arrays and structures when it comes to things like XML children and XML attributes. There's also all kinds of pseudo-node-wrappers that can be used as well.

@Helgi,

Ha ha, I try to cover a lot of ground :)

Reply to this Comment

@Joey,

Awesome - glad this helped. Even years later, I have not found a better way to move XML nodes from one document to another; I think dipping down into Java is the only way (without doing a lot of copying).

Reply to this Comment

This solved a problem I had a while back and I've used it quite a lot since - but now found a problem. (CF8)

If the values in nodeB happen to have unicode escaped characters in them, then this UDF unescapes them.

For example:

nA:

  • <?xml version="1.0" encoding="UTF-8"?>
  • <fai timestamp="234345454"/>

nB:

  • <?xml version="1.0" encoding="UTF-8"?>
  • <cima>
  • <record>
  • <rlocation>Le Davier, Etrich&#xe9;</rlocation>
  • </record>
  • </cima>
  • <cfset XmlAppend(nA,xmlParse(nB)) />

result:

  • <?xml version="1.0" encoding="UTF-8"?>
  • <fai timestamp="234345454">
  • <cima>
  • <record>
  • <rlocation>Le Davier, Etrich</rlocation>
  • </record>
  • </cima>
  • </fai>

Reply to this Comment

Having struggled with this for some time, the problem is not as described above.

It is actually appending just fine.

I think I must have done something to my dev server (CF8) which causes xmlParse() not to parse entities correctly because on my production server it is working as expected.

Even though that is Railo it's probably a .jar I've replaced by mistake on my dev server or something which is causing the problem....

Oh well... Happy new year anyway.

Reply to this Comment

@Richard,

Is it possible that it's just outputting oddly when you debug it? Character encoding is a magical concept that my brain only understands slightly. I know there's a number of things that need to be in alignment for (moons, planets, etc.) in order for UTF-8 characters to display properly. This is doubly true when you add a database to the mix.

Reply to this Comment

Post A Comment

?
You — Get Out Of My Dreams, Get Into My Comments
Live in the Now
Oops!
Comment Etiquette: Please do not post spam. Please keep the comments on-topic. Please do not post unrelated questions or large chunks of code. And, above all, please be nice to each other - we're trying to have a good conversation here.