Getting Week, Month, And Year Dates Based On A Given Date In ColdFusion
Posted May 7, 2007 at 9:30 AM
When working with any sort of ColdFusion event or calendar system, you will need to get dates based on other dates. In my experience, given a date, it is often necessary to get the start and end dates of week containing the given date; the start and end dates of the month containing the given date; the start and end dates of the calendar (display) month containing the given date; and, the start and end dates of the year containing the given date. The purpose of this post is just to demonstrate how to get those date values.
For all of these, assume we built the "Today" date using:
Launch code in new window » Download code as text file »
- <!---
- Get the current date. We are going to Fix()
- ColdFusion's Now() date/time stamp to remove the
- time, leaving us with just the date value.
- --->
- <cfset dtToday = Fix( Now() ) />
Getting the start and end date of the week:
Launch code in new window » Download code as text file »
- <!--- Get the week start date. --->
- <cfset dtWeekStart = (dtToday - DayOfWeek( dtToday ) + 1) />
-
- <!--- Get the week end date. --->
- <cfset dtWeekEnd = (dtToday + (7 - DayOfWeek( dtToday ))) />
-
-
- <!--- Output the dates: --->
- Today: #DateFormat( dtToday )#<br />
- Week Start: #DateFormat( dtWeekStart )#<br />
- Week End: #DateFormat( dtWeekEnd )#<br />
...gives us:
Today: 07-May-07
Week Start: 06-May-07
Week End: 12-May-07
Getting the start and end date of the month:
Launch code in new window » Download code as text file »
- <!--- Get the month start date. --->
- <cfset dtMonthStart = (dtToday - Day( dtToday ) + 1) />
-
- <!--- Get the month end date. --->
- <cfset dtMonthEnd = (
- dtToday + (DaysInMonth( dtToday ) - Day( dtToday ))
- ) />
-
-
- <!--- Output the dates: --->
- Today: #DateFormat( dtToday )#<br />
- Month Start: #DateFormat( dtMonthStart )#<br />
- Month End: #DateFormat( dtMonthEnd )#<br />
...gives us:
Today: 07-May-07
Month Start: 01-May-07
Month End: 31-May-07
Getting the start and end date of the year:
Launch code in new window » Download code as text file »
- <!---
- Get the year start date. These dates never change with
- exception of the year. The first date of the year will
- always be January 1st.
- --->
- <cfset dtYearStart = CreateDate(
- Year( dtToday ),
- 1,
- 1
- ) />
-
-
- <!---
- Get the year end date. These dates never change with
- exception of the year. The last date of the year will
- always be December 31st.
- --->
- <cfset dtYearEnd = CreateDate(
- Year( dtToday ),
- 12,
- 31
- ) />
-
-
- <!--- Output the dates: --->
- Today: #DateFormat( dtToday )#<br />
- Year Start: #DateFormat( dtYearStart )#<br />
- Year End: #DateFormat( dtYearEnd )#<br />
...gives us:
Today: 07-May-07
Year Start: 01-Jan-07
Year End: 31-Dec-07
Getting the start and end date of the displayed calendar month (may or may not spill over into other numeric months):
Launch code in new window » Download code as text file »
- <!---
- The calendar display dates are ever slightly more
- complicated. It helps to work off of the previously
- calculated month start/end dates to make them easier
- to work with.
- --->
- <cfset dtCalendarMonthStart = (
- dtMonthStart - DayOfWeek( dtMonthStart ) + 1
- ) />
-
- <!--- Get the end date. --->
- <cfset dtCalendarMonthEnd = (
- dtMonthEnd + (7 - DayOfWeek( dtMonthEnd ))
- ) />
-
-
- <!--- Output the dates: --->
- Today: #DateFormat( dtToday )#<br />
- Cal. Month Start: #DateFormat( dtCalendarMonthStart )#<br />
- Cal. Month End: #DateFormat( dtCalendarMonthEnd )#<br />
...give us:
Today: 07-May-07
Cal. Month Start: 29-Apr-07
Cal. Month End: 02-Jun-07
Notice that in all of the outputs, we are using DateFormat(). The reason for this is that all of the date math that we are doing results in numeric dates rather than string-formatted dates. This is all good and fine if you are looping and querying using CFQueryParam, but if you try to use IsDate() on the resultant dates, this will fail; you much use IsNumericDate() with numeric dates (note: string-formatted dates will also work with IsNumericDate()).
Download Code Snippet ZIP File
Post Comment | Ask Ben | Permalink | Other Searches | Print Page
Reader Comments
Last time I had to do this (which was quite some time ago), I don't remember it being this simple. Now, I'm not quite sure of calculating the start and end date of the year (does it change from 1/1/year(now()) and 12/31/year(now())?) but calculating the beginning of the week given a date I recall was a PITA back then.
You should wrap at least that into a function on cflib, if one doesn't already exist.
@Sam,
Let me see what I can do... I know that biggest leap for me came when I found out that I could mess with dates with out using DateAdd() and DateDiff() methods... the code just became so much cleaner (but perhaps slightly less intuitive, especially if you are not used to doing date-math).
Well, I never liked using the date functions - they are just unintuitive in my opinion. I think getting around it like you have done improves the readability and understanding of what the code is doing (and I never thought about trying it out myself).
I'm using parts of this solution along with an entry on general calendaring to produce a calendar with Monday as the week start and Saturday and Sunday combined in a column. I've got the layout right, but:
What if I wanted to start the week on Monday (2) and end on Sunday (1). I'm thinking that I need to, somehow, override the DayOfWeek to that Monday is 1 and Sunday is 7. I think I'm onto something here and think it could be quite simple, but I just can't seem to get down to it.
I'm also guessing that there might be--should be--a CF setting, hopefully local to a template, that will allow this reassignment/shifting of 1 to Monday.
@Macbuoy,
Check this out (I think this might help you out):
http://www.bennadel.com/index.cfm?dax=blog:691.view
i know its been a while to the post but i was trying to loop through last three week including current week..somehow the loop gives wrong set of dates
basically trying to get
8/16 to 8/22 8/9 to 8/15 8/2 to 8/8 7/26 to 8/1
any help will be appreciated...thanks
@Mili,
I use the CFLoop tag to loop over dates quite effectively.
http://www.bennadel.com/blog/136-Using-CFLoop-To-Loop-Over-ColdFusion-Dates.htm
