Ben Nadel
On User Experience (UX) Design, JavaScript, ColdFusion, Node.js, Life, and Love.
I am the chief technical officer at InVision App, Inc - a prototyping and collaboration platform for designers, built by designers. I also rock out in JavaScript and ColdFusion 24x7.
Meanwhile on Twitter
Loading latest tweet...
Ben Nadel at TechCrunch Disrupt (New York, NY) with:

Searching Directories And File Content Using ColdFusion

By Ben Nadel on
Tags: ColdFusion

Earlier this week, Nick G over on the CF-Talk list asked about searching through the content of the files in a given directory. I would say this is a task best performed by something other than ColdFusion... but of course, I am not one to turn down the chance to write some sweet ass ColdFusion code. And so, last night, I wrote this ColdFusion user defined function (UDF) that takes either a directory path or an array of file paths and a phrase to search for and returns an array of file paths that contain the given phrase. The search can be done either as a literal text search or as a regular expression search.

Here is the SearchFiles() ColdFusion UDF:

  • <cffunction
  • name="SearchFiles"
  • access="public"
  • returntype="array"
  • output="false"
  • hint="Searchs files for the given values. Returns an array of file paths.">
  •  
  • <!--- Define arguments. --->
  • <cfargument
  • name="Path"
  • type="any"
  • required="true"
  • hint="This is either a directory path or an array of file paths which we will be searching."
  • />
  •  
  • <cfargument
  • name="Criteria"
  • type="string"
  • required="true"
  • hint="The values for which we are searching the file contents."
  • />
  •  
  • <cfargument
  • name="Filter"
  • type="string"
  • required="false"
  • default="cfm,css,htm,html,js,txt,xml"
  • hint="List of file extensions that we are going to allow."
  • />
  •  
  • <cfargument
  • name="IsRegex"
  • type="boolean"
  • required="false"
  • default="false"
  • hint="Flags whether or not the search criteria is a regular expression."
  • />
  •  
  •  
  • <!--- Define the local scope. --->
  • <cfset var LOCAL = StructNew() />
  •  
  •  
  • <!---
  • Check to see if we are dealing with a directory path.
  • If we are, we are going to want to get those paths
  • and convert it to an array of file paths.
  • --->
  • <cfif IsSimpleValue( ARGUMENTS.Path )>
  •  
  • <!---
  • Get all the files in the given directory. We are
  • going to ensure that only files are returned in
  • the resultant query. We don't want to deal with
  • any directories.
  • --->
  • <cfdirectory
  • action="LIST"
  • directory="#ARGUMENTS.Path#"
  • name="LOCAL.FileQuery"
  • filter="*.*"
  • />
  •  
  • <!---
  • Now that we have the query, we want to create an
  • array of the file names.
  • --->
  • <cfset LOCAL.Paths = ArrayNew( 1 ) />
  •  
  • <!--- Loop over the query and set up the values. --->
  • <cfloop query="LOCAL.FileQuery">
  •  
  • <cfset ArrayAppend(
  • LOCAL.Paths,
  • (LOCAL.FileQuery.directory & "\" & LOCAL.FileQuery.name)
  • ) />
  •  
  • </cfloop>
  •  
  • <cfelse>
  •  
  • <!---
  • For consistency sake, just store the path argument
  • into our local paths value so that we can refer to
  • this and the query-route the same way (see above).
  • --->
  • <cfset LOCAL.Paths = ARGUMENTS.Path />
  •  
  • </cfif>
  •  
  •  
  • <!---
  • ASSERT: At this point, whether we were passed in a
  • directory path or an array of file paths, we now have
  • an array of file paths that we are going to search
  • in the variable LOCAL.Paths.
  • --->
  •  
  •  
  • <!---
  • Create an array in which we will store the file paths
  • that had matching criteria.
  • --->
  • <cfset LOCAL.MatchingPaths = ArrayNew( 1 ) />
  •  
  •  
  • <!---
  • Clean up the filter to be used in a regular expression.
  • We are going to turn the list into an OR reg ex.
  • --->
  • <cfset ARGUMENTS.Filter = ARGUMENTS.Filter.ReplaceAll(
  • "[^\w\d,]+",
  • ""
  • ).ReplaceAll(
  • ",",
  • "|"
  • ) />
  •  
  •  
  • <!--- Loop over the file paths in our paths array. --->
  • <cfloop
  • index="LOCAL.PathIndex"
  • from="1"
  • to="#ArrayLen( LOCAL.Paths )#"
  • step="1">
  •  
  •  
  • <!---
  • Get a short hand to the current path. This is
  • not necessary but just makes referencing the
  • path easier.
  • --->
  • <cfset LOCAL.Path = LOCAL.Paths[ LOCAL.PathIndex ] />
  •  
  •  
  • <!---
  • Check to see if this file path is allowed. Either
  • we have no file filters or we do and this file
  • has one of them.
  • --->
  • <cfif (
  • (NOT Len( ARGUMENTS.Filter )) OR
  • (
  • REFindNoCase(
  • "(#ARGUMENTS.Filter#)$",
  • LOCAL.Path
  • )
  • ))>
  •  
  •  
  • <!---
  • This is a file that we can use. Read in the
  • contents of the file.
  • --->
  • <cffile
  • action="READ"
  • file="#LOCAL.Path#"
  • variable="LOCAL.FileData"
  • />
  •  
  •  
  • <!---
  • Check to see what kind of search we are going.
  • Is it a straight-up value search or is it a
  • regular expression search?
  • --->
  • <cfif (
  • (
  • ARGUMENTS.IsRegex AND
  • REFindNoCase(
  • ARGUMENTS.Criteria,
  • LOCAL.FileData
  • )
  • ) OR
  • (
  • (NOT ARGUMENTS.IsRegex) AND
  • FindNoCase(
  • ARGUMENTS.Criteria,
  • LOCAL.FileData
  • )
  • )
  • )>
  •  
  • <!---
  • This is a good file path. Add it to the
  • list of successful file paths.
  • --->
  • <cfset ArrayAppend(
  • LOCAL.MatchingPaths,
  • LOCAL.Path
  • ) />
  •  
  • </cfif>
  •  
  • </cfif>
  •  
  • </cfloop>
  •  
  •  
  • <!--- Return the array of matching file paths. --->
  • <cfreturn LOCAL.MatchingPaths />
  •  
  • </cffunction>

As you can see, there is no real magic going on here. The algorithm just loops over the file paths, checks them against the file extension filter, reads in the content, searches for the phrase, and then returns all matching file paths. The only difference between a standard search and a regular expression search is that the standard search uses FindNoCase() where as the regular expression search uses REFindNoCase().

Here is an example of how to search the current directory:

  • <!--- Search entire directory. --->
  • <cfset arrMatchingPaths = SearchFiles(
  • Path = ExpandPath( "./" ),
  • Criteria = "she pondered"
  • ) />

... and here is how you might call it using an array of file paths:

  • <!--- Create an array of file paths to search. --->
  • <cfset arrPaths = ArrayNew( 1 ) />
  •  
  • <!--- Add paths to the array. --->
  • <cfset ArrayAppend(
  • arrPaths,
  • ExpandPath( "./file_search_data.htm" )
  • ) />
  •  
  • <cfset ArrayAppend(
  • arrPaths,
  • ExpandPath( "./file_search_data.html" )
  • ) />
  •  
  • <cfset ArrayAppend(
  • arrPaths,
  • ExpandPath( "./file_search_data.txt" )
  • ) />
  •  
  •  
  • <!--- Search given files for the regular expression match. --->
  • <cfset arrMatchingPaths = SearchFiles(
  • Path = arrPaths,
  • Criteria = "she (pondered|licked|kissed)",
  • Filter = "txt",
  • IsRegex = true
  • ) />

So that's that. I am sure there are many ways of doing this in ColdFusion that have already been done, but you know me - I love to reinvent the wheel (no matter what Sean might say - I love getting the machinery firing full blast). One modification that could be neat would be to search the file name itself. This would be an easy modification (perhaps for the next attempt).



Reader Comments

Overhead... and that sort of a demo would be beyond my area of expertise. Plus, verity requires duplicating data (for the index). This can take random directories / file paths on the fly. This doesn't require any planning.

Reply to this Comment

Hi all,

Thanks for the code!!
I tried to search for a file content by using your code and it works well! :)

However, it only works well when searching for english text content, but asian lanaguages (eg. chinese, japanese, etc) cannot.

Just wondering if it is possible to search for the asian language content from a file? Any change to the code itself?

Regards,
Ronald

Reply to this Comment

@Ronald,

I am not sure of how you would go about this. My thoughts, and this is probably NOT the way to go, would be to run regular expression searches and just replace all the foreign extended characters with something like .{1} where it matches one character.

So, something like "Espanol" where is has the "n" with the tilde, you would maybe search for "Espa.{1}ol". Of course, this does not guarantee a good match. There has god to be a much better way to do this.

Reply to this Comment

Works like a charm Ben!

One question, though. Is there a way to limit the area of the file that is searched? I am using this to search through some pages on our website. The only problem is, when the search term happens to be in the meta tags of the pages, those pages come up whether or not the search term is in the readable content of the page.

Thanks!

Reply to this Comment

@Jason,

Hmmm, that's a tough question. When you have to matching something NOT within something else, I'll typically break the problem down into two separate matches; or rather, I'll match what I DO want and what I DON'T want and then I'll make the judgement call per-match.

While this is not what you are asking, I used a similar approach when replacing a string that was NOT within another string:

http://www.bennadel.com/blog/1861-Ask-Ben-Replacing-A-String-That-Is-Not-Inside-Of-Another-String.htm

In that example, I'm replacing; but, you could rework something like that to work with find, not replace.

If your pages are XML-compliant (strict XHTML), then you could also parse the XHTML into an XML document and search based on node text. This would give you a bit more control; but, it will only work if your markup is rather strict.

Reply to this Comment

Hi,

I'm a CF newbie...I inherited this site at our company that is built in CF.

I am trying to find the pages that would contain certain strings...so this function will be very useful...

If only, I knew how/ where to put these code snippets.

Thanks.

RD

Reply to this Comment

@RDev,

There's a lot of strategies for defining user defined functions in a ColdFusion application. Typically, people put them in a file and then CFInclude them into each page. Or, you can create some sort of UDF object and then instantiate it and cache it within your Application scope (for example).

Good luck!

Reply to this Comment

Great code example! Thanks for this.

I think this works if you only want to search one directory but doesn't work if your looking for a recursive file search. How would you go about creating a search that works similar but recursive? A file index?

Thanks,
Paul

Reply to this Comment

@Paul,

Good question - I think what you could do is turn the function into a recursive one base on the type of path being passed in. So, for example, if you pass in a path that is a simple value (ie. a string) and then you run:

directoryExists( arguments.path )

... to see if it's a directory. If it *is* a directory, you can query for all entries in that directory and then recursively call the searchFiles() function for each nested path.

Does that make sense? That could be a fun little blog post.

Reply to this Comment

Hi Ben
My Coldfusion skills are limited and wonder if you could help. I do not get any output when I run this UDF, other then your commented text. The local path is definitely correct and I am using a search word I know exists in the files. Running CF 9. I am sure I am missing something simple. Any ideas?
Thanks
Larry

Reply to this Comment

Hi Ben. Sorry, the problem I had was too stupid to fess up to. All set now.

This UDF will be very useful for me.

Thanks!
Larry

Reply to this Comment

I've tried everything under the sun that I could think of to get this seemingly simplistic (thanks to you) code to work. But no luck...

What am I missing? I tried adding the SearchFiles.cfc code to the page as an include, but that didn't work.

Can you help? SearchFiles.cfc is in a 'component' folder, as stated below.

  • <cfset variables.fileloc = createObject("component", "SearchFiles")>
  •  
  • <cfset arrMatchingPaths = fileloc.SearchFiles(
  • Path = ExpandPath( "./" ),
  • Criteria = "A482"
  • ) />

Reply to this Comment

Hello Sir,
I have reviewed the code, however, sorry to ask, how do I search from a page? Would you have a sample search page?

Reply to this Comment

@Larry,

Ha ha - no worries my friend - we all have those moments :)

@Jo,

Try CFDump'ing out "expandPath( './' )" before the component is invoked; double check your paths are correct.

Reply to this Comment

Post A Comment

You — Get Out Of My Dreams, Get Into My Comments
Live in the Now
Oops!
Comment Etiquette: Please do not post spam. Please keep the comments on-topic. Please do not post unrelated questions or large chunks of code. And, above all, please be nice to each other - we're trying to have a good conversation here.