Searching Directories And File Content Using ColdFusion : Kinky Solutions : A Student's Perspective by Ben Nadel

Searching Directories And File Content Using ColdFusion

Posted March 1, 2007 at 8:06 AM

Earlier this week, Nick G over on the CF-Talk list asked about searching through the content of the files in a given directory. I would say this is a task best performed by something other than ColdFusion... but of course, I am not one to turn down the chance to write some sweet ass ColdFusion code. And so, last night, I wrote this ColdFusion user defined function (UDF) that takes either a directory path or an array of file paths and a phrase to search for and returns an array of file paths that contain the given phrase. The search can be done either as a literal text search or as a regular expression search.

Here is the SearchFiles() ColdFusion UDF:

Launch code in new window » Download code as text file »

<cffunction
name="SearchFiles"
access="public"
returntype="array"
output="false"
hint="Searchs files for the given values. Returns an array of file paths.">
<cfargument
name="Path"
type="any"
required="true"
hint="This is either a directory path or an array of file paths which we will be searching."
/>
<cfargument
name="Criteria"
type="string"
required="true"
hint="The values for which we are searching the file contents."
/>
<cfargument
name="Filter"
type="string"
required="false"
default="cfm,css,htm,html,js,txt,xml"
hint="List of file extensions that we are going to allow."
/>
<cfargument
name="IsRegex"
type="boolean"
required="false"
default="false"
hint="Flags whether or not the search criteria is a regular expression."
/>
<cfset var LOCAL = StructNew() />
<!---
Check to see if we are dealing with a directory path.
If we are, we are going to want to get those paths
and convert it to an array of file paths.
--->
<cfif IsSimpleValue( ARGUMENTS.Path )>
<!---
Get all the files in the given directory. We are
going to ensure that only files are returned in
the resultant query. We don't want to deal with
any directories.
--->
<cfdirectory
action="LIST"
directory="#ARGUMENTS.Path#"
name="LOCAL.FileQuery"
filter="*.*"
/>
<!---
Now that we have the query, we want to create an
array of the file names.
--->
<cfset LOCAL.Paths = ArrayNew( 1 ) />
<cfloop query="LOCAL.FileQuery">
<cfset ArrayAppend(
LOCAL.Paths,
(LOCAL.FileQuery.directory & "\" & LOCAL.FileQuery.name)
) />
</cfloop>
<cfelse>
<!---
For consistency sake, just store the path argument
into our local paths value so that we can refer to
this and the query-route the same way (see above).
--->
<cfset LOCAL.Paths = ARGUMENTS.Path />
</cfif>
<!---
ASSERT: At this point, whether we were passed in a
directory path or an array of file paths, we now have
an array of file paths that we are going to search
in the variable LOCAL.Paths.
--->
<!---
Create an array in which we will store the file paths
that had matching criteria.
--->
<cfset LOCAL.MatchingPaths = ArrayNew( 1 ) />
<!---
Clean up the filter to be used in a regular expression.
We are going to turn the list into an OR reg ex.
--->
<cfset ARGUMENTS.Filter = ARGUMENTS.Filter.ReplaceAll(
"[^\w\d,]+",
""
).ReplaceAll(
",",
"|"
) />
<cfloop
index="LOCAL.PathIndex"
from="1"
to="#ArrayLen( LOCAL.Paths )#"
step="1">
<!---
Get a short hand to the current path. This is
not necessary but just makes referencing the
path easier.
--->
<cfset LOCAL.Path = LOCAL.Paths[ LOCAL.PathIndex ] />
<!---
Check to see if this file path is allowed. Either
we have no file filters or we do and this file
has one of them.
--->
<cfif (
(NOT Len( ARGUMENTS.Filter )) OR
(
REFindNoCase(
"(#ARGUMENTS.Filter#)$",
LOCAL.Path
)
))>
<!---
This is a file that we can use. Read in the
contents of the file.
--->
<cffile
action="READ"
file="#LOCAL.Path#"
variable="LOCAL.FileData"
/>
<!---
Check to see what kind of search we are going.
Is it a straight-up value search or is it a
regular expression search?
--->
<cfif (
(
ARGUMENTS.IsRegex AND
REFindNoCase(
ARGUMENTS.Criteria,
LOCAL.FileData
)
) OR
(
(NOT ARGUMENTS.IsRegex) AND
FindNoCase(
ARGUMENTS.Criteria,
LOCAL.FileData
)
)
)>
<!---
This is a good file path. Add it to the
list of successful file paths.
--->
<cfset ArrayAppend(
LOCAL.MatchingPaths,
LOCAL.Path
) />
</cfif>
</cfif>
</cfloop>
<cfreturn LOCAL.MatchingPaths />
</cffunction>

As you can see, there is no real magic going on here. The algorithm just loops over the file paths, checks them against the file extension filter, reads in the content, searches for the phrase, and then returns all matching file paths. The only difference between a standard search and a regular expression search is that the standard search uses FindNoCase() where as the regular expression search uses REFindNoCase().

Here is an example of how to search the current directory:

Launch code in new window » Download code as text file »

<cfset arrMatchingPaths = SearchFiles(
Path = ExpandPath( "./" ),
Criteria = "she pondered"
) />

... and here is how you might call it using an array of file paths:

Launch code in new window » Download code as text file »

<cfset arrPaths = ArrayNew( 1 ) />
<cfset ArrayAppend(
arrPaths,
ExpandPath( "./file_search_data.htm" )
) />
<cfset ArrayAppend(
arrPaths,
ExpandPath( "./file_search_data.html" )
) />
<cfset ArrayAppend(
arrPaths,
ExpandPath( "./file_search_data.txt" )
) />
<cfset arrMatchingPaths = SearchFiles(
Path = arrPaths,
Criteria = "she (pondered|licked|kissed)",
Filter = "txt",
IsRegex = true
) />

So that's that. I am sure there are many ways of doing this in ColdFusion that have already been done, but you know me - I love to reinvent the wheel (no matter what Sean might say - I love getting the machinery firing full blast). One modification that could be neat would be to search the file name itself. This would be an easy modification (perhaps for the next attempt).

Download Code Snippet ZIP File

What Has Two Thumbs And Is Attending CFUnited Express NYC... THIS GUY!

ColdFusion Query Maintains Current Row Even When Passed By Reference

Reader Comments

Why not just use Verity (or Lucene for the Blue Dragon crowd)?

Posted by Christopher Wigginton on Mar 1, 2007 at 4:44 PM

Overhead... and that sort of a demo would be beyond my area of expertise. Plus, verity requires duplicating data (for the index). This can take random directories / file paths on the fly. This doesn't require any planning.

Posted by Ben Nadel on Mar 1, 2007 at 5:03 PM

Hi all,

Thanks for the code!!
I tried to search for a file content by using your code and it works well! :)

However, it only works well when searching for english text content, but asian lanaguages (eg. chinese, japanese, etc) cannot.

Just wondering if it is possible to search for the asian language content from a file? Any change to the code itself?

Regards,
Ronald

Posted by Ronald Heng on Mar 18, 2007 at 9:10 AM

@Ronald,

I am not sure of how you would go about this. My thoughts, and this is probably NOT the way to go, would be to run regular expression searches and just replace all the foreign extended characters with something like .{1} where it matches one character.

So, something like "Espanol" where is has the "n" with the tilde, you would maybe search for "Espa.{1}ol". Of course, this does not guarantee a good match. There has god to be a much better way to do this.

Posted by Ben Nadel on Mar 19, 2007 at 7:36 AM

Post Comment | Ask Ben

Searching Directories And File Content Using ColdFusion : Kinky Solutions : A Student's Perspective by Ben Nadel